home *** CD-ROM | disk | FTP | other *** search
/ BBS Toolkit / BBS Toolkit.iso / windows / mrun211.zip / MRUN211B.WAS < prev    next >
Text File  |  1993-05-01  |  10KB  |  394 lines
  1. ;MailRun v2.11:  Part B, changesettings
  2. ;1992-1993 Gerald P. Sully, all rights reserved.
  3.  
  4. #comment
  5. **************************************************************************
  6. **************************************************************************
  7. * 
  8. * This file contains routines related to changing MailRun
  9. * settings.  It puts up the MailRun Settings dialog box, and
  10. * writes any changes to the *.MRN file.  If the user changes
  11. * the MailRun directory, it will move all MailRun Files to the
  12. * new directory and stop the script.
  13. * 
  14. **************************************************************************
  15. **************************************************************************
  16. #endcomment
  17.  
  18. #define MRUN211B
  19. #define MRUN211BC
  20. #define MRUN211AB
  21.  
  22. #include "mrun211.h"
  23.  
  24. #comment
  25. *********************************************************************
  26. * 
  27. * MAIN()
  28. * 
  29. * Calls checkchild(), checkdir(), settingsbox(), getfirstitem(),
  30. * loadsettings(), changemailrun(), makemailrunlist(),
  31. * menudim(), newmailrun(), interfaceon(), changemrundir(),
  32. * writesettings(), findstring(), checkchanged(),
  33. * 
  34. * Allows the user to change the settings in the [MailRun]
  35. * section of the *.MRN file.
  36. * 
  37. *********************************************************************
  38. #endcomment
  39.  
  40. proc main
  41. string LastMRunDir, LastMailDir, LastReplyDir
  42. string LastDLDir, LastULDir, LastMRun
  43. integer dialogstatus
  44.     menudim()
  45.     checkchild()
  46.     LastMRun = MailRun
  47.     loadsettings(MailRun)
  48.     LastMailDir = MailDir
  49.     LastReplyDir = ReplyDir
  50.     LastDLDir = DownloadDir
  51.     LastULDir = UploadDir
  52.     if FLAGS & DEFAULTS
  53.         MailRunList = "mailrun.ini"
  54.         MailRunTrunc = "mailrun.ini"
  55.         LastMRunDir = MailRunDir
  56.     else
  57.         findfirst MailRun
  58.         MailRunTrunc = $FILENAME
  59.         makemailrunlist()
  60.     endif
  61.     FLAGS &= UNCHANGED
  62.     settingsbox()
  63.     if !(FLAGS & DEFAULTS)
  64.         disable CTRL 242
  65.     endif
  66.     if LogRun == 0
  67.         disable CTRL 71
  68.         disable CTRL 72
  69.     endif
  70.     if FLAGS & RUNNING
  71.         disable CTRL 170
  72.     endif
  73.     if FLAGS & NEW
  74.         newmailrun()
  75.         getfirstitem()
  76.         LastMRun = MailRun
  77.     endif
  78.     interfaceon()
  79.     while 1
  80.         dialogstatus = $DIALOG
  81.         switch dialogstatus
  82.             case 10
  83.                 ;User selected "Save"
  84.                 ;if the directories chosen in settingsbox()
  85.                 ;don't exist, create them
  86.                 if checkdir(&MailRunDir, LastMRunDir) && \
  87.                     checkdir(&MailDir, LastMailDir) && \
  88.                     checkdir(&ReplyDir, LastReplyDir) && \
  89.                     checkdir(&DownloadDir, LastDLDir) && \
  90.                     checkdir(&UploadDir, LastULDir)
  91.                     ;if all directories were successfully created...
  92.                     chdir MailRunDir
  93.                     if FLAGS & DEFAULTS
  94.                         writesettings(MailRunIni)
  95.                     else
  96.                         writesettings(MailRun)
  97.                     endif
  98.                 else
  99.                     updatedlg 128
  100.                 endif
  101.                 FLAGS &= UNCHANGED
  102.             endcase
  103.             case 11
  104.                 ;User selected "Done"
  105.                 if checkchanged()
  106.                     ;if user has no unsaved changes...
  107.                     if (FLAGS & DEFAULTS) && !(findstring(LastMRunDir, MailRunDir))
  108.                         ;if user has changed the MailRun Directory    
  109.                         changemrundir(LastMRunDir)
  110.                         updatedlg 128
  111.                     else
  112.                         exit
  113.                     endif
  114.                 endif
  115.             endcase
  116.             case 70
  117.                 ;User selected the Log MailRun checkbox
  118.                 if LogRun == 0
  119.                     ;If logging was turned off, disable the other checkboxes
  120.                     disable CTRL 71
  121.                     disable CTRL 72
  122.                 else
  123.                     ;Otherwise, enable the checkboxes
  124.                     enable CTRL 71
  125.                     enable CTRL 72
  126.                 endif
  127.                 FLAGS |= CHANGED
  128.                 updatedlg 1
  129.             endcase
  130.             case 170
  131.                 ;User changed mailrun with combobox
  132.                 if checkchanged()
  133.                     changemailrun()
  134.                     getfirstitem()
  135.                     LastMRun = MailRun
  136.                     updatedlg -1
  137.                 else
  138.                     findfirst MailRun
  139.                     MailRunTrunc = $FILENAME
  140.                     updatedlg 512
  141.                 endif
  142.             endcase
  143.             case 230
  144.             case 231
  145.             case 232
  146.             case 233
  147.             case 234
  148.             case 235
  149.             case 236
  150.             case 237
  151.             case 238
  152.             case 239
  153.             case 240
  154.             case 241
  155.             case 242
  156.             case 71
  157.             case 72
  158.             case 73
  159.                 FLAGS |= CHANGED
  160.             endcase
  161.         endswitch
  162.     endwhile
  163. endproc
  164.  
  165.  
  166. #comment
  167. *********************************************************************
  168. * 
  169. * CHECKDIR()
  170. * 
  171. * Called by main()
  172. * 
  173. * Creates a directory.  If the directory already exists or
  174. * was successfully created, a value of 0 is returned.  If
  175. * an error occurs, the name of NewDir is changed to that
  176. * of OldDir, and a value of 1 is returned.
  177. * 
  178. *********************************************************************
  179. #endcomment
  180.  
  181. func checkdir : integer
  182. strparm NewDir, OldDir
  183.     chdir NewDir
  184.     if FAILURE
  185.         mkdir NewDir
  186.         if FAILURE
  187.             usermsg "Unable to create directory %s" NewDir
  188.             NewDir = OldDir
  189.             return 0
  190.         endif
  191.     endif
  192.     return 1
  193. endfunc
  194.  
  195.  
  196. #comment
  197. *********************************************************************
  198. * 
  199. * NEWMAILRUN()
  200. * 
  201. * Called by main()
  202. * 
  203. * Calls fverify(), filesave(), makemrn(), makemailrunlist(),
  204. * makefullname()
  205. * 
  206. * Prompts the user for the name of a new *.MRN file, checks
  207. * the name, and calls routines to create it.
  208. * 
  209. *********************************************************************
  210. #endcomment
  211.  
  212. proc newmailrun
  213. string NewRun, temp
  214.     ;Make sure the entered MailRun ID is the correct length
  215.     ;and that it doesn't already exist
  216.     while 1
  217.         NewRun = ""
  218.         sdlginput "New MailRun" \
  219.             "Enter the ID of the new mailrun:" NewRun
  220.         if FAILURE
  221.             exit
  222.         endif
  223.         strlwr NewRun
  224.         if not fverify(NewRun)
  225.             usermsg \
  226.             "A mailrun ID must be a valid DOS file name without the extension."
  227.             loopwhile
  228.         endif
  229.         strfmt temp "%s.mrn" NewRun
  230.         NewRun = makefullname(MailRunDir, temp)
  231.         if isfile NewRun
  232.             errormsg "That MailRun already exists!"
  233.         else
  234.             exitwhile
  235.         endif
  236.     endwhile
  237.  
  238.     ;Update the previous mailrun
  239.     filesave()
  240.     delfile MailRun
  241.     ;Create the new mailrun
  242.     MailRunTrunc = temp
  243.     makemrn()
  244.     makemailrunlist()
  245.     updatedlg -1
  246. endproc
  247.  
  248.  
  249. #comment
  250. *********************************************************************
  251. * 
  252. * CHANGEMRUNDIR()
  253. * 
  254. * Called by main()
  255. * 
  256. * Calls movefiles(), fileexit(), makefullname()
  257. * 
  258. * Requests confirmation, moves all MailRun support files
  259. * to the new MailRun Directory, and shuts down so that the
  260. * user can restart.
  261. * 
  262. *********************************************************************
  263. #endcomment
  264.  
  265. proc changemrundir
  266. strparm LastMRunDir
  267. string WarnMsg, CleanupFile
  268. integer Response
  269.     strfmt WarnMsg "All MailRun files will be moved to`r`n`r`n\
  270.       %s`r`n`r`nand MailRun will have to be restarted.`r`n`r`nDo you wish \
  271. continue?" MailRunDir
  272.     sdlgmsgbox "MailRun Message" WarnMsg QUESTION YESNO Response 2
  273.     switch Response
  274.         case 6
  275.             ;User selected "Yes"
  276.             cleanupfile = makefullname(TempDir, "CLEANUP.TMP")
  277.             profilerd cleanupfile "cleanup" "LastMRun" MailRun
  278.             findfirst MailRun
  279.             MailRunTrunc = $FILENAME
  280.             profilewr MailRunIni "MailRun" "MailRunDir" MailRunDir
  281.             movefiles(LastMRunDir, MailRunDir, "MRUN211?.WA?")
  282.             movefiles(LastMRunDir, MailRunDir, "MRUN211.H")
  283.             movefiles(LastMRunDir, MailRunDir, "NEWFILES.WA?")
  284.             movefiles(LastMRunDir, MailRunDir, "TERMINAL.WA?")
  285.             movefiles(LastMRunDir, MailRunDir, "*.MRN")
  286.             movefiles(LastMRunDir, MailRunDir, "*.?DX")
  287.             movefiles(LastMRunDir, MailRunDir, "*.?BF")
  288.             movefiles(LastMRunDir, MailRunDir, "MRUNICON.DLL")
  289.             movefiles(LastMRunDir, MailRunDir, "MAILRUN.WRI")
  290.             fileexit()
  291.         endcase
  292.         case 7
  293.             ;User selected "No"
  294.             MailRunDir = LastMRunDir
  295.         endcase
  296.     endswitch
  297. endproc    
  298.  
  299.  
  300. #comment
  301. *********************************************************************
  302. * 
  303. * MOVEFILES()
  304. * 
  305. * Called by changemrundir()
  306. * 
  307. * Calls makefullname()
  308. * 
  309. * Moves files matching the given filespec from their current
  310. * location to the MailRun directory.
  311. * 
  312. *********************************************************************
  313. #endcomment
  314.  
  315. proc movefiles
  316. strparm OldDir, NewDir, Spec
  317. string OldFile, NewFile, OldSpec
  318.     OldSpec = makefullname(OldDir, Spec)
  319.     findfirst OldSpec
  320.     while FOUND
  321.         if not strcmpi $FILENAME "MRUN211.WAS"
  322.             if not strcmpi $FILENAME "MRUN211.WAX"
  323.                statmsg "Moving %s" $FILENAME
  324.                 OldFile = makefullname(OldDir, $FILENAME)
  325.                 NewFile = makefullname(NewDir, $FILENAME)
  326.                 copyfile OldFile NewFile
  327.                 delfile OldFile
  328.             endif
  329.         endif
  330.         findnext
  331.     endwhile
  332. endproc
  333.  
  334.  
  335. #comment
  336. *********************************************************************
  337. * 
  338. * SETTINGSBOX()
  339. * 
  340. * Called by main()
  341. * 
  342. * Displays the MailRun Settings dialog box.
  343. * 
  344. *********************************************************************
  345. #endcomment
  346.  
  347. proc settingsbox
  348. destroydlg
  349. HelpPage = 4
  350. dialogbox 15 36 340 222 15 "MailRun Settings" HELPID HelpPage
  351.    groupbox 10 28 200 96 "Directories" shadow
  352.    text  16 42 71 8 right "MailRun Directory:"
  353.    text  16 58 71 8 right "Mail Directory:"
  354.    text  16 74 71 8 right "Reply Directory:"
  355.    text  16 90 71 8 right "Download Directory:"
  356.    text  16 106 71 8 right "Upload Directory:"
  357.    editbox 91 56 110 12 MailDir
  358.    editbox 91 72 110 12 ReplyDir
  359.    editbox 91 88 110 12 DownloadDir
  360.    editbox 91 104 110 12 UploadDir
  361.    groupbox 224 28 102 96 "Parameters" shadow
  362.    text  234 42 62 8 right "Dial Attempts:"
  363.    text  234 58 62 8 right "Dial Timeout:"
  364.    text  234 74 62 8 right "Dial Pause:"
  365.    text  234 90 62 8 right "Idle Timeout:"
  366.    text  234 106 62 8 right "Packets to Save:"
  367.    editbox 300 40 16 12 DialAttempts
  368.    editbox 300 56 16 12 DialTimeout
  369.    editbox 300 72 16 12 DialPause
  370.    editbox 300 88 16 12 IdleTime
  371.    editbox 300 104 16 12 SavePackets
  372.    groupbox 10 132 124 59 "Logging" shadow
  373.    checkbox 18 144 112 12 "Capture mailrun to log file" LogRun
  374.    checkbox 18 158 112 12 "Append to existing log file" AppendLog
  375.    checkbox 18 172 112 12 "Capture ANSI codes in log file" AnsiInLog
  376.    checkbox 18 200 134 12 "Filter duplicates from d/l database" NewfileFilter
  377.    groupbox 144 132 184 59 "Utilities" shadow
  378.    text  145 146 65 8 right "Archive Utility:"
  379.    text  145 160 65 8 right "QWK Mail Reader:"
  380.    text  145 174 65 8 right "Log File Viewer:"
  381.    editbox 214 144 107 12 Archiver
  382.    editbox 214 158 107 12 QWKReader
  383.    editbox 214 172 107 12 LogViewer
  384.    pushbutton 191 200 40 14 "&Save" normal default
  385.    pushbutton 252 200 40 14 "&Done" normal
  386.    text  100 11 52 8 right "Settings for:"
  387.    combobox 156 9 72 42 MailRunList MailRunTrunc sort
  388.    editbox 91 40 110 12 MailRunDir
  389. enddialog
  390. endproc
  391.  
  392.  
  393.  
  394.